(defun download-images% (uri directory)
  "Download images from a thread (without error handling)"
  (with-simple-restart (thread-skip "Skip downloading this thread")
    (let* ((thread (make-thread uri))
           (pathname (get-directory-pathname directory (directory-name thread))))
      (let ((files (remove-extensions (image-sources thread) *ignored-extensions*)))
        (ensure-directories-exist pathname)
        (format t "Downloading total of ~d images~%" (length files))
        (mapc (lambda (file)
                (format t ".")
                (force-output)
                (destructuring-bind (uri . name) file
                  (let ((file-path (merge-pathnames name pathname)))
                    (tagbody retry
                       (restart-case
                           (if (not (open file-path :direction :probe))
                               (let ((data (make-request uri)))
                                 (with-open-file (output file-path
                                                         :direction :output
                                                         :if-does-not-exist :create
                                                         :element-type '(unsigned-byte 8))
                                   (write-sequence data output))))
                         (file-skip ()
                           :report "Skip downloading file" ())
                         (file-retry ()
                           :report "Retry downloading file" (go retry)))))))
              files))))
  (format t "~%")
  t)

(defun try-restarts (restarts)
  "Invoke the first available restart from list"
  (mapc (lambda (restart)
          (if (find-restart restart)
              (invoke-restart restart)))
        restarts))

(defun handle-conditions (condition)
  "Handle conditions automatically or fall back to the debugger"
  (princ condition *error-output*)
  (terpri *error-output*)
  (force-output *error-output*)
  (typecase condition
    (unknown-resource
     ;; Skip the thread and continue with a new one
     (invoke-restart 'thread-skip))
    ((or bad-response-code usocket:timeout-error)
     ;; Try to skip a file first
     (try-restarts '(file-skip thread-skip)))))

(defun download-images (uri directory)
  "Download images from a thread. URI is a desired resource WWW address.
 All files will be saved to DIRECTORY + some guessed name, based on the
 name of the thread or URI."
  (handler-bind
      (((or file-error usocket:socket-error
            image-downloader-error)
        #'handle-conditions))
    (download-images% uri directory)))